(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2012 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA

 *)

{$INCLUDE "options.inc"}

unit uLandGraphics;

interface

uses uFloat, uConsts, uTypes;

type TRangeArray = array[0..31] of record

                                   Left, Right: LongInt;

                                   end;

     PRangeArray = ^TRangeArray;

function  addBgColor(OldColor, NewColor: LongWord): LongWord;

function  SweepDirty: boolean;

function  Despeckle(X, Y: LongInt): Boolean;

procedure Smooth(X, Y: LongInt);

function  CheckLandValue(X, Y: LongInt; LandFlag: Word): boolean;

function  DrawExplosion(X, Y, Radius: LongInt): Longword;

procedure DrawHLinesExplosions(ar: PRangeArray; Radius: LongInt; y, dY: LongInt; Count: Byte);

procedure DrawTunnel(X, Y, dX, dY: hwFloat; ticks, HalfWidth: LongInt);

procedure FillRoundInLand(X, Y, Radius: LongInt; Value: Longword);

procedure FillRoundInLandWithIce(X, Y, Radius: LongInt);

procedure ChangeRoundInLand(X, Y, Radius: LongInt; doSet, isCurrent: boolean);

function  LandBackPixel(x, y: LongInt): LongWord;

procedure DrawLine(X1, Y1, X2, Y2: LongInt; Color: Longword);

procedure DrawThickLine(X1, Y1, X2, Y2, radius: LongInt; color: Longword);

procedure DumpLandToLog(x, y, r: LongInt);

procedure DrawIceBreak(x, y, iceRadius, iceHeight: Longint);

function TryPlaceOnLand(cpX, cpY: LongInt; Obj: TSprite; Frame: LongInt; doPlace: boolean; indestructible: boolean): boolean;

implementation

uses SDLh, uLandTexture, uVariables, uUtils, uDebug;

function addBgColor(OldColor, NewColor: LongWord): LongWord;

// Factor ranges from 0 to 100% NewColor

var

    oRed, oBlue, oGreen, oAlpha, nRed, nBlue, nGreen, nAlpha: byte;

begin

    oAlpha := (OldColor shr AShift);

    nAlpha := (NewColor shr AShift);

    // shortcircuit

    if (oAlpha = 0) or (nAlpha = $FF) then

        begin

        addBgColor:= NewColor;

        exit

        end;

    // Get colors

    oRed   := (OldColor shr RShift);

    oGreen := (OldColor shr GShift);

    oBlue  := (OldColor shr BShift);

    nRed   := (NewColor shr RShift);

    nGreen := (NewColor shr GShift);

    nBlue  := (NewColor shr BShift);

    // Mix colors

    nRed   := min(255,((nRed*nAlpha) div 255) + ((oRed*oAlpha*byte(255-nAlpha)) div 65025));

    nGreen := min(255,((nGreen*nAlpha) div 255) + ((oGreen*oAlpha*byte(255-nAlpha)) div 65025));

    nBlue  := min(255,((nBlue*nAlpha) div 255) + ((oBlue*oAlpha*byte(255-nAlpha)) div 65025));

    nAlpha := min(255, oAlpha + nAlpha);

    addBgColor := (nAlpha shl AShift) or (nRed shl RShift) or (nGreen shl GShift) or (nBlue shl BShift);

end;

procedure FillCircleLines(x, y, dx, dy: LongInt; Value: Longword);

var i: LongInt;

begin

if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[y + dy, i] and lfIndestructible) = 0 then

            Land[y + dy, i]:= Value;

if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[y - dy, i] and lfIndestructible) = 0 then

            Land[y - dy, i]:= Value;

if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[y + dx, i] and lfIndestructible) = 0 then

            Land[y + dx, i]:= Value;

if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[y - dx, i] and lfIndestructible) = 0 then

            Land[y - dx, i]:= Value;

end;

procedure ChangeCircleLines(x, y, dx, dy: LongInt; doSet, isCurrent: boolean);

var i: LongInt;

begin

if not doSet then

    begin

    if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y + dy, i]:= Land[y + dy, i] and $FF7F

            else if Land[y + dy, i] and $007F > 0 then

                Land[y + dy, i]:= (Land[y + dy, i] and $FF80) or ((Land[y + dy, i] and $7F) - 1);

    if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y - dy, i]:= Land[y - dy, i] and $FF7F

            else if Land[y - dy, i] and $007F > 0 then

                Land[y - dy, i]:= (Land[y - dy, i] and $FF80) or ((Land[y - dy, i] and $7F) - 1);

    if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y + dx, i]:= Land[y + dx, i] and $FF7F

            else if Land[y + dx, i] and $007F > 0 then

                Land[y + dx, i]:= (Land[y + dx, i] and $FF80) or ((Land[y + dx, i] and $7F) - 1);

    if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y - dx, i]:= Land[y - dx, i] and $FF7F

            else if Land[y - dx, i] and $007F > 0 then

                Land[y - dx, i]:= (Land[y - dx, i] and $FF80) or ((Land[y - dx, i] and $7F) - 1)

    end

else

    begin

    if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y + dy, i]:= Land[y + dy, i] or $80

            else if Land[y + dy, i] and $007F < 127 then

                Land[y + dy, i]:= (Land[y + dy, i] and $FF80) or ((Land[y + dy, i] and $7F) + 1);

    if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y - dy, i]:= Land[y - dy, i] or $80

            else if Land[y - dy, i] and $007F < 127 then

                Land[y - dy, i]:= (Land[y - dy, i] and $FF80) or ((Land[y - dy, i] and $7F) + 1);

    if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y + dx, i]:= Land[y + dx, i] or $80

            else if Land[y + dx, i] and $007F < 127 then

                Land[y + dx, i]:= (Land[y + dx, i] and $FF80) or ((Land[y + dx, i] and $7F) + 1);

    if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if isCurrent then

                Land[y - dx, i]:= Land[y - dx, i] or $80

            else if Land[y - dx, i] and $007F < 127 then

                Land[y - dx, i]:= (Land[y - dx, i] and $FF80) or ((Land[y - dx, i] and $7F) + 1)

    end

end;

procedure FillRoundInLand(X, Y, Radius: LongInt; Value: Longword);

var dx, dy, d: LongInt;

begin

dx:= 0;

dy:= Radius;

d:= 3 - 2 * Radius;

while (dx < dy) do

    begin

    FillCircleLines(x, y, dx, dy, Value);

    if (d < 0) then

        d:= d + 4 * dx + 6

    else

        begin

        d:= d + 4 * (dx - dy) + 10;

        dec(dy)

        end;

    inc(dx)

    end;

if (dx = dy) then

    FillCircleLines(x, y, dx, dy, Value);

end;

procedure ChangeRoundInLand(X, Y, Radius: LongInt; doSet, isCurrent: boolean);

var dx, dy, d: LongInt;

begin

dx:= 0;

dy:= Radius;

d:= 3 - 2 * Radius;

while (dx < dy) do

    begin

    ChangeCircleLines(x, y, dx, dy, doSet, isCurrent);

    if (d < 0) then

        d:= d + 4 * dx + 6

    else

        begin

        d:= d + 4 * (dx - dy) + 10;

        dec(dy)

        end;

    inc(dx)

    end;

if (dx = dy) then

    ChangeCircleLines(x, y, dx, dy, doSet, isCurrent)

end;

procedure FillLandCircleLines0(x, y, dx, dy: LongInt);

var i, t: LongInt;

begin

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

end;

function isLandscapeEdge(weight:Longint):boolean; inline;

begin

    result := (weight < 8) and (weight >= 2);

end;

function getPixelWeight(x, y:Longint): Longint;

var

    i, j:Longint;

begin

    result := 0;

    for i := x - 1 to x + 1 do

        for j := y - 1 to y + 1 do

        begin

        if (i < 0) or

           (i > LAND_WIDTH - 1) or

           (j < 0) or

           (j > LAND_HEIGHT -1) then

               begin               

                result := 0;

                exit;

               end;

        if ((Land[j, i] and $FF00) = 0) and ((Land[j, i] and lfIce) = 0) then

           begin

           result := result + 1;

           end;

        end;

end;

procedure drawIcePixel(y, x:Longint);

var

    iceSurface: PSDL_Surface;

    icePixels: PLongwordArray;

    pictureX, pictureY: LongInt;

    w, c: LongWord;

    weight: Longint;

begin

    // So. 3 parameters here. Ice colour, Ice opacity, and a bias on the greyscaled pixel towards lightness

    iceSurface:= SpritesData[sprIceTexture].Surface;

    icePixels := iceSurface^.pixels;

    w:= LandPixels[y, x];

    w:= round(((w shr RShift and $FF) * RGB_LUMINANCE_RED +

          (w shr BShift and $FF) * RGB_LUMINANCE_GREEN +

          (w shr GShift and $FF) * RGB_LUMINANCE_BLUE));

    if w < 128 then w:= w+128;

    if w > 255 then w:= 255;

    w:= (w shl RShift) or (w shl BShift) or (w shl GShift) or (LandPixels[y,x] and AMask);

    //LandPixels[y, x]:= w;

    LandPixels[y, x]:= addBgColor(w, IceColor);

    LandPixels[y, x]:= addBgColor(LandPixels[y, x], icePixels^[iceSurface^.w * (y mod iceSurface^.h) + (x mod iceSurface^.w)]);

end;

function getIncrementInquarter(dx, dy, quarter: Longint): Longint; inline;

const directionX : array [0..3] of Longint = (0, 0, 1, -1);

const directionY : array [0..3] of Longint = (1, -1, 0, 0);

begin

    getIncrementInquarter := directionX[quarter] * dx + directionY[quarter] * dy;

end;

function getIncrementInquarter2(dx, dy, quarter: Longint): Longint; inline;

const directionY : array [0..3] of Longint = (0, 0, 1, 1);

const directionX : array [0..3] of Longint = (1, 1, 0, 0);

begin

    getIncrementInquarter2 := directionX[quarter] * dx + directionY[quarter] * dy;

end;

procedure FillLandCircleLinesIce(x, y, dx, dy: LongInt);

var q, i, t, px, py: LongInt;

begin

for q := 0 to 3 do

    begin

    t:= y + getIncrementInquarter(dx, dy, q);

    if (t and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - getIncrementInquarter2(dx, dy, q), 0) to Min(x + getIncrementInquarter2(dx, dy, q), LAND_WIDTH - 1) do

            if Land[t, i] and lfIce = 0 then

                begin

                if (cReducedQuality and rqBlurryLand) = 0 then

                    begin

                    px:= i; py:= t

                    end

                else

                    begin

                    px:= i div 2; py:= t div 2

                    end;

                if isLandscapeEdge(getPixelWeight(i, t)) then

                    begin

                    if (LandPixels[py, px] and AMask < 255) and (LandPixels[py, px] and AMask > 0) then

                        LandPixels[py, px] := (IceEdgeColor and not AMask) or (LandPixels[py, px] and AMask)

                    else if (LandPixels[py, px] and AMask < 255) or (Land[t, i] > 255) then

                        LandPixels[py, px] := IceEdgeColor

                    end

                else if Land[t, i] > 255 then

                    begin

                    drawIcePixel(py, px)

                    end;

                if Land[t, i] > 255 then Land[t, i] := Land[t, i] or lfIce and not lfDamaged;

                end;

    end

end;

procedure FillRoundInLandWithIce(X, Y, Radius: LongInt);

var dx, dy, d: LongInt;

    landRect: TSDL_Rect;

begin

dx:= 0;

dy:= Radius;

d:= 3 - 2 * Radius;

while (dx < dy) do

    begin

    FillLandCircleLinesIce(x, y, dx, dy);

    if (d < 0) then

        d:= d + 4 * dx + 6

    else

        begin

        d:= d + 4 * (dx - dy) + 10;

        dec(dy)

        end;

    inc(dx)

    end;

if (dx = dy) then

    FillLandCircleLinesIce(x, y, dx, dy);

landRect.x := min(max(x - Radius, 0), LAND_WIDTH - 1);

landRect.y := min(max(y - Radius, 0), LAND_HEIGHT - 1);

landRect.w := min(2*Radius, LAND_WIDTH - landRect.x - 1);

landRect.h := min(2*Radius, LAND_HEIGHT - landRect.y - 1);

UpdateLandTexture(landRect.x, landRect.w, landRect.y, landRect.h, true);        

end;

procedure DrawIceBreak(x, y, iceRadius, iceHeight: Longint);

var

    i, j: integer;

    landRect: TSDL_Rect;

begin

for i := min(max(x - iceRadius, 0), LAND_WIDTH - 1) to min(max(x + iceRadius, 0), LAND_WIDTH - 1) do

    begin

    for j := min(max(y, 0), LAND_HEIGHT - 1) to min(max(y + iceHeight, 0), LAND_HEIGHT - 1) do

        begin

        if land[j, i] = 0 then

            begin

                land[j, i] := lfIce;                

                drawIcePixel(j, i);

            end;

        end;        

    end;

landRect.x := min(max(x - iceRadius, 0), LAND_WIDTH - 1);

landRect.y := min(max(y, 0), LAND_HEIGHT - 1);

landRect.w := min(2*iceRadius, LAND_WIDTH - landRect.x - 1);

landRect.h := min(iceHeight, LAND_HEIGHT - landRect.y - 1);

UpdateLandTexture(landRect.x, landRect.w, landRect.y, landRect.h, true);        

end;

function FillLandCircleLinesBG(x, y, dx, dy: LongInt): Longword;

var i, t, by, bx: LongInt;

    cnt: Longword;

begin

cnt:= 0;

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then

                LandPixels[by, bx]:= 0

            end;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then

                LandPixels[by, bx]:= 0

            end;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then

                LandPixels[by, bx]:= 0

            end;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end