(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2011 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA

 *)

{$INCLUDE "options.inc"}

{$IF GLunit = GL}{$DEFINE GLunit:=GL,GLext}{$ENDIF}

unit uWorld;

interface

uses SDLh, uGears, uConsts, uFloat, uRandom, uTypes;

procedure initModule;

procedure freeModule;

procedure InitWorld;

procedure ResetWorldTex;

procedure DrawWorld(Lag: LongInt);

procedure DrawWorldStereo(Lag: LongInt; RM: TRenderMode);

procedure ShowMission(caption, subcaption, text: ansistring; icon, time : LongInt);

procedure HideMission;

procedure ShakeCamera(amount: LongInt);

procedure InitCameraBorders;

procedure MoveCamera;

procedure onFocusStateChanged;

implementation

uses

    uStore,

    uMisc,

    uIO,

    uLocale,

    uSound,

    uAmmos,

    uVisualGears,

    uChat,

    uLandTexture,

    GLunit,

    uVariables,

    uUtils,

    uTextures,

    uRender,

    uCaptions,

    uCursor,

    uCommands,

    uMobile

    ;

var cWaveWidth, cWaveHeight: LongInt;

    AMxOffset, AMyOffset, AMShiftTarget, AMShift, SlotsNum: LongInt;

    tmpSurface: PSDL_Surface;

    fpsTexture: PTexture;

    timeTexture: PTexture;

    FPS: Longword;

    CountTicks: Longword;

    SoundTimerTicks: Longword;

    prevPoint: TPoint;

    amSel: TAmmoType = amNothing;

    missionTex: PTexture;

    missionTimer: LongInt;

    stereoDepth: GLfloat;

const cStereo_Sky           = 0.0500;

      cStereo_Horizon       = 0.0250;

      cStereo_MidDistance   = 0.0175;

      cStereo_Water_distant = 0.0125;

      cStereo_Land          = 0.0075;

      cStereo_Water_near    = 0.0025;

      cStereo_Outside       = -0.0400;

// helper functions to create the goal/game mode string

function AddGoal(s: ansistring; gf: longword; si: TGoalStrId; i: LongInt): ansistring;

var t: ansistring;

begin

    if (GameFlags and gf) <> 0 then

        begin

        t:= inttostr(i);

        s:= s + format(trgoal[si], t) + '|'

        end;

    AddGoal:= s;

end;

function AddGoal(s: ansistring; gf: longword; si: TGoalStrId): ansistring;

begin

    if (GameFlags and gf) <> 0 then

        s:= s + trgoal[si] + '|';

    AddGoal:= s;

end;

procedure InitWorld;

var i, t: LongInt;

    cp: PClan;

    g: ansistring;

begin

missionTimer:= 0;

if (GameFlags and gfRandomOrder) <> 0 then  // shuffle them up a bit

    begin

    for i:= 0 to ClansCount * 4 do

        begin

        t:= GetRandom(ClansCount);

        if t <> 0 then

            begin

            cp:= ClansArray[0];

            ClansArray[0]:= ClansArray[t];

            ClansArray[t]:= cp;

            ClansArray[t]^.ClanIndex:= t;

            ClansArray[0]^.ClanIndex:= 0;

            if (LocalClan = t) then

                LocalClan:= 0

            else if (LocalClan = 0) then

                LocalClan:= t

            end;

        end;

    CurrentTeam:= ClansArray[0]^.Teams[0];

    end;

// if special game flags/settings are changed, add them to the game mode notice window and then show it

g:= ''; // no text/things to note yet

// add custom goals from lua script if there are any

if LuaGoals <> '' then

    g:= LuaGoals + '|';

// check different game flags (goals/game modes first for now)

g:= AddGoal(g, gfKing, gidKing); // king?

g:= AddGoal(g, gfTagTeam, gidTagTeam); // tag team mode?

// other important flags

g:= AddGoal(g, gfForts, gidForts); // forts?

g:= AddGoal(g, gfLowGravity, gidLowGravity); // low gravity?

g:= AddGoal(g, gfInvulnerable, gidInvulnerable); // invulnerability?

g:= AddGoal(g, gfVampiric, gidVampiric); // vampirism?

g:= AddGoal(g, gfKarma, gidKarma); // karma?

g:= AddGoal(g, gfPlaceHog, gidPlaceHog); // placement?

g:= AddGoal(g, gfArtillery, gidArtillery); // artillery?

g:= AddGoal(g, gfSolidLand, gidSolidLand); // solid land?

g:= AddGoal(g, gfSharedAmmo, gidSharedAmmo); // shared ammo?

g:= AddGoal(g, gfResetHealth, gidResetHealth);

g:= AddGoal(g, gfAISurvival, gidAISurvival);

g:= AddGoal(g, gfInfAttack, gidInfAttack);

g:= AddGoal(g, gfResetWeps, gidResetWeps);

g:= AddGoal(g, gfPerHogAmmo, gidPerHogAmmo);

// modified damage modificator?

if cDamagePercent <> 100 then

    g:= AddGoal(g, gfAny, gidDamageModifier, cDamagePercent);

// fade in

ScreenFade:= sfFromBlack;

ScreenFadeValue:= sfMax;

ScreenFadeSpeed:= 1;

// modified mine timers?

if cMinesTime <> 3000 then

    begin

    if cMinesTime = 0 then

        g:= AddGoal(g, gfAny, gidNoMineTimer)

    else if cMinesTime < 0 then

        g:= AddGoal(g, gfAny, gidRandomMineTimer)

    else

        g:= AddGoal(g, gfAny, gidMineTimer, cMinesTime div 1000);

    end;

// if the string has been set, show it for (default timeframe) seconds

if g <> '' then

    ShowMission(trgoal[gidCaption], trgoal[gidSubCaption], g, 1, 0);

cWaveWidth:= SpritesData[sprWater].Width;

//cWaveHeight:= SpritesData[sprWater].Height;

cWaveHeight:= 32;

InitCameraBorders();

uCursor.init();

prevPoint.X:= 0;

prevPoint.Y:= cScreenHeight div 2;

WorldDx:=  -(LAND_WIDTH div 2) + cScreenWidth div 2;

WorldDy:=  -(LAND_HEIGHT - (playHeight div 2)) + (cScreenHeight div 2);

//aligns it to the bottom of the screen, minus the border

SkyOffset:= 0;

HorizontOffset:= 0;

{$IFDEF MOBILE}

AMxOffset:= 0;

if isPhone() then

    AMyOffset:= AMSlotSize

else

    AMyOffset:= AMSlotSize * 2;

{$ELSE}

AMxOffset:= 10;

AMyOffset:= 60;

{$ENDIF}

end;

procedure InitCameraBorders;

begin

cGearScrEdgesDist:= min(2 * cScreenHeight div 5, 2 * cScreenWidth div 5);

end;

// for uStore texture resetting

procedure ResetWorldTex;

begin

    FreeTexture(fpsTexture);

    fpsTexture:= nil;

    FreeTexture(timeTexture);

    timeTexture:= nil;

    FreeTexture(missionTex);

    missionTex:= nil;

end;

procedure ShowAmmoMenu;

const MENUSPEED = 15;

const BORDERSIZE = 2;

var x, y, i, t, g: LongInt;

    Slot, Pos, STurns: LongInt;

    Ammo: PHHAmmo;

begin

    if (TurnTimeLeft = 0) or (not CurrentTeam^.ExtDriven and (((CurAmmoGear = nil)

    or ((Ammoz[CurAmmoGear^.AmmoType].Ammo.Propz and ammoprop_AltAttack) = 0)) and hideAmmoMenu)) then

        bShowAmmoMenu:= false;

    if bShowAmmoMenu then

    // show ammo menu

        begin

        FollowGear:= nil;

        if AMShift = AMShiftTarget then

{$IFDEF MOBILE}

            prevPoint.Y:= 0;

{$ELSE}

            prevPoint.X:= 0;

{$ENDIF}

        if (cReducedQuality and rqSlowMenu) <> 0 then

            AMShift:= 0

        else

            if AMShift > MENUSPEED then

                dec(AMShift, MENUSPEED)

            else

                AMShift:= 0;

        end

    else

    // hide ammo menu

        begin

        if AMShift = 0 then

            begin

            CursorPoint.X:= cScreenWidth shr 1;

            CursorPoint.Y:= cScreenHeight shr 1;

            prevPoint:= CursorPoint;

            end;

        if (cReducedQuality and rqSlowMenu) <> 0 then

            AMShift:= AMShiftTarget+2

        else

            if AMShift < (AMShiftTarget - MENUSPEED) then

                inc(AMShift, MENUSPEED)

            else

                AMShift:= AMShiftTarget;

        end;

    // give the assigned ammo to hedgehog

    Ammo:= nil;

    if (CurrentTeam <> nil) and (CurrentHedgehog <> nil)

    and (not CurrentTeam^.ExtDriven) and (CurrentHedgehog^.BotLevel = 0) then

        Ammo:= CurrentHedgehog^.Ammo

    else if (LocalAmmo <> -1) then

        Ammo:= GetAmmoByNum(LocalAmmo);

    Pos:= -1;

    if Ammo = nil then

        begin

        bShowAmmoMenu:= false;

        exit

        end;

    SlotsNum:= 0;

{$IFDEF MOBILE}

    Slot:= cMaxSlotIndex;

    for i:= 0 to cMaxSlotIndex do

        if((i = 0) and (Ammo^[i,1].Count > 0)) or ((i <> 0) and (Ammo^[i,0].Count > 0)) then

            inc(SlotsNum);

    x:= AMxOffset - ((SlotsNum * AMSlotSize) shr 1);

    y:= cScreenHeight - AMShiftTarget + AMShift;

    dec(x, BORDERSIZE);

    DrawSprite(sprAMCorners, x, y - BORDERSIZE, 0);//top left corner

    for i:= 0 to cMaxSlotAmmoIndex +1 do

        DrawSprite(sprAMBorderVertical, x, y + i * AMSlotSize, 0);

    DrawSprite(sprAMCorners, x, y + ((cMaxSlotAmmoIndex+2) * AMSlotSize) , 2);//bottom left corner

    inc(x, BORDERSIZE);

    for i:= 0 to SlotsNum -2 do

        DrawSprite(sprAMSlot, x + i * AMSlotSize, y, 2);

    DrawSprite(sprAMSlot, x + (SlotsNum-1) * AMSlotSize, y, 1);

    inc(y, AMSlotSize);

    for i:= 0 to cMaxSlotIndex do

        if ((i = 0) and (Ammo^[i, 1].Count > 0)) or ((i <> 0) and (Ammo^[i, 0].Count > 0)) then

            begin

            if (CursorPoint.X >= x) and (CursorPoint.X <= x + AMSlotSize) then

                Slot:= i;

            DrawSprite(sprAMBorderHorizontal, x, y - BORDERSIZE - AMSlotSize, 0);

            g:= 0;

            for t:=0 to cMaxSlotAmmoIndex do

                begin

                DrawSprite(sprAMSlot, x, y + t * AMSlotSize, 1);

                if (Ammo^[i, t].Count > 0) then

                    begin

                    if (Ammo^[i, t].AmmoType <> amNothing) then

                        begin

                        STurns:= Ammoz[Ammo^[i, t].AmmoType].SkipTurns - CurrentTeam^.Clan^.TurnNumber;

                        if STurns >= 0 then //weapon not usable yet, draw grayed out with turns remaining

                            begin

                            DrawSprite(sprAMAmmosBW, x, y + (g * AMSlotSize) + 1, LongInt(Ammo^[i, t].AmmoType)-1);

                            if STurns < 100 then

                                DrawSprite(sprTurnsLeft, x + AMSlotSize-16, y + (g + 1) * AMSlotSize-16, STurns);

                            end

                        else //draw colored version

                            DrawSprite(sprAMAmmos, x, y + (g * AMSlotSize) + 1, LongInt(Ammo^[i, t].AmmoType)-1);

                        if (Slot = i) and (CursorPoint.Y <= (cScreenHeight - y) - (g * AMSlotSize)) and

                           (CursorPoint.Y >= (cScreenHeight - y) - ((g+1) * AMSlotSize)) then

                            begin

                            if (STurns < 0) then

                                DrawSprite(sprAMSlot, x, y + (g * AMSlotSize), 0);

                            Pos:= t;

                            end;

                        inc(g);

                        end;

                    end;

                end;

            DrawSprite(sprAMBorderHorizontal, x, y + ((cMaxSlotAmmoIndex+1) * AMSlotSize), 1);

            inc(x, AMSlotSize);

            end;

    DrawSprite(sprAMCorners, x, y + ((cMaxSlotAmmoIndex+1) * AMSlotSize), 3); //bottom right corner

    DrawSprite(sprAMCorners, x - BORDERSIZE, y + (AMSlotSize * cMaxSlotAmmoIndex), 1);//top right  corner

    dec(y, AMSlotSize);

    for i:= 0 to cMaxSlotAmmoIndex + 1 do

        DrawSprite(sprAMBorderVertical, x,y + i * AMSlotSize, 1);

    inc(y, AMSlotSize);

{$ELSE}

    Slot:= 0;

    x:= (cScreenWidth shr 1) - AMShiftTarget + AMShift;

    y:= cScreenHeight - AMyOffset;

    DrawSprite(sprAMCorners, x - BORDERSIZE, y, 2);

    for i:= 0 to cMaxSlotAmmoIndex + 1 do

        DrawSprite(sprAMBorderHorizontal, x + i * AMSlotSize, y, 1);

    DrawSprite(sprAMCorners, x + AMShiftTarget - AMxOffset, y, 3);

    dec(y, AMSlotSize);

    DrawSprite(sprAMBorderVertical, x - BORDERSIZE, y, 0);

    for i:= 0 to cMaxSlotAmmoIndex do

        DrawSprite(sprAMSlot, x + i * AMSlotSize, y, 2);

    DrawSprite(sprAMSlot, x + (cMaxSlotAmmoIndex + 1) * AMSlotSize, y, 1);

    DrawSprite(sprAMBorderVertical, x + AMShiftTarget - AMxOffset, y, 1);

    for i:= cMaxSlotIndex downto 0 do

        if ((i = 0) and (Ammo^[i, 1].Count > 0)) or ((i <> 0) and (Ammo^[i, 0].Count > 0)) then

            begin

            if (cScreenHeight - CursorPoint.Y >= y - AMSlotSize) and (cScreenHeight - CursorPoint.Y <= y) then

                Slot:= i;

            dec(y, AMSlotSize);

            inc(SlotsNum);

            DrawSprite(sprAMBorderVertical, x - BORDERSIZE, y, 0);

            DrawSprite(sprAMSlot, x, y, 1);

            DrawSprite(sprAMSlotKeys, x, y + 1, i);

            t:= 0;

            g:= 1;

            while (t <= cMaxSlotAmmoIndex) and (Ammo^[i, t].Count > 0) do

                begin

                DrawSprite(sprAMSlot, x + g * AMSlotSize, y, 1);

                if (Ammo^[i, t].AmmoType <> amNothing) then

                    begin

                    STurns:= Ammoz[Ammo^[i, t].AmmoType].SkipTurns - CurrentTeam^.Clan^.TurnNumber;

                    if STurns >= 0 then

                        begin

                        DrawSprite(sprAMAmmosBW, x + g * AMSlotSize, y + 1, LongInt(Ammo^[i, t].AmmoType)-1);

                        if STurns < 100 then

                            DrawSprite(sprTurnsLeft, x + (g + 1) * AMSlotSize - 16, y + AMSlotSize - 16, STurns);

                        end else

                        DrawSprite(sprAMAmmos, x + g * AMSlotSize, y + 1, LongInt(Ammo^[i, t].AmmoType)-1);

                    if (Slot = i) and (CursorPoint.X >= x + g * AMSlotSize) and

                       (CursorPoint.X <= x + (g + 1) * AMSlotSize) then

                        begin

                        if (STurns < 0) then

                            DrawSprite(sprAMSlot, x + g * AMSlotSize, y, 0);

                        Pos:= t;

                        end;

                    inc(g)

                    end;

                    inc(t)

                end;

            for g:= g to cMaxSlotAmmoIndex + 1 do

                DrawSprite(sprAMSlot, x + g * AMSlotSize, y, 1);

            DrawSprite(sprAMBorderVertical, x + AMShiftTarget - AMxOffset, y, 1);

            end;

    dec(y, BORDERSIZE);

    DrawSprite(sprAMCorners, x - BORDERSIZE, y, 0);

    for i:= 0 to cMaxSlotAmmoIndex + 1 do

        DrawSprite(sprAMBorderHorizontal, x + i * AMSlotSize, y, 0);

    DrawSprite(sprAMCorners, x + AMShiftTarget - AMxOffset, y, 1);

{$ENDIF}

    if (Pos >= 0) then

        begin

        if (Ammo^[Slot, Pos].Count > 0) and (Ammo^[Slot, Pos].AmmoType <> amNothing) then

            begin

            if (amSel <> Ammo^[Slot, Pos].AmmoType) or (WeaponTooltipTex = nil) then

                begin

                amSel:= Ammo^[Slot, Pos].AmmoType;

                RenderWeaponTooltip(amSel)

                end;

{$IFDEF MOBILE}

            DrawTexture(AMxOffset - ((SlotsNum * AMSlotSize) shr 1) + (AMSlotSize shr 1),

                        cScreenHeight - AMShiftTarget + AMShift + (Ammoz[Ammo^[Slot, Pos].AmmoType].NameTex^.h shr 1),

                        Ammoz[Ammo^[Slot, Pos].AmmoType].NameTex);

            if Ammo^[Slot, Pos].Count < AMMO_INFINITE then

                DrawTexture(AMxOffset + ((SlotsNum * AMSlotSize) shr 1) - Round(Ammoz[Ammo^[Slot, Pos].AmmoType].NameTex^.h * 1.5),

                            cScreenHeight - AMShiftTarget + AMShift + (Ammoz[Ammo^[Slot, Pos].AmmoType].NameTex^.h shr 1),

                            CountTexz[Ammo^[Slot, Pos].Count]);

{$ELSE}

            DrawTexture(cScreenWidth div 2 - (AMShiftTarget - 10) + AMShift, cScreenHeight - AMyOffset - 25, Ammoz[Ammo^[Slot, Pos].AmmoType].NameTex);

            if Ammo^[Slot, Pos].Count < AMMO_INFINITE then

                DrawTexture(cScreenWidth div 2 + AMxOffset - 45, cScreenHeight - AMyOffset - 25, CountTexz[Ammo^[Slot, Pos].Count]);

{$ENDIF}

            if bSelected and (Ammoz[Ammo^[Slot, Pos].AmmoType].SkipTurns - CurrentTeam^.Clan^.TurnNumber < 0) then

                begin

                bShowAmmoMenu:= false;

                SetWeapon(Ammo^[Slot, Pos].AmmoType);

                bSelected:= false;

                FreeWeaponTooltip;

                exit

                end;

            end

        end

    else

        FreeWeaponTooltip;

    if (WeaponTooltipTex <> nil) and (AMShift = 0) then

{$IFDEF MOBILE}

        ShowWeaponTooltip(-WeaponTooltipTex^.w div 2, cScreenHeight - (AMShiftTarget + AMSlotSize + WeaponTooltipTex^.h));

{$ELSE}

        ShowWeaponTooltip(x - WeaponTooltipTex^.w - 3, Min(y + 1, cScreenHeight - WeaponTooltipTex^.h - 40));

{$ENDIF}

    bSelected:= false;

    if AMShift = 0 then

        DrawSprite(sprArrow, CursorPoint.X, cScreenHeight - CursorPoint.Y, (RealTicks shr 6) mod 8)

end;

procedure DrawWater(Alpha: byte; OffsetY: LongInt);

var VertexBuffer: array [0..3] of TVertex2f;

    r: TSDL_Rect;

    lw, lh: GLfloat;

begin

if SuddenDeathDmg then

    begin

    SDWaterColorArray[0].a := Alpha;