(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2012 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA

 *)

{$INCLUDE "options.inc"}

unit uLandGraphics;

interface

uses uFloat, uConsts, uTypes;

type PRangeArray = ^TRangeArray;

     TRangeArray = array[0..31] of record

                                   Left, Right: LongInt;

                                   end;

function  addBgColor(OldColor, NewColor: LongWord): LongWord;

function  SweepDirty: boolean;

function  Despeckle(X, Y: LongInt): Boolean;

procedure Smooth(X, Y: LongInt);

function  CheckLandValue(X, Y: LongInt; LandFlag: Word): boolean;

function  DrawExplosion(X, Y, Radius: LongInt): Longword;

procedure DrawHLinesExplosions(ar: PRangeArray; Radius: LongInt; y, dY: LongInt; Count: Byte);

procedure DrawTunnel(X, Y, dX, dY: hwFloat; ticks, HalfWidth: LongInt);

procedure FillRoundInLand(X, Y, Radius: LongInt; Value: Longword);

procedure ChangeRoundInLand(X, Y, Radius: LongInt; doSet: boolean);

function  LandBackPixel(x, y: LongInt): LongWord;

procedure DrawLine(X1, Y1, X2, Y2: LongInt; Color: Longword);

function TryPlaceOnLand(cpX, cpY: LongInt; Obj: TSprite; Frame: LongInt; doPlace: boolean; indestructible: boolean): boolean;

implementation

uses SDLh, uLandTexture, uVariables, uUtils, uDebug;

function addBgColor(OldColor, NewColor: LongWord): LongWord;

// Factor ranges from 0 to 100% NewColor

var

    oRed, oBlue, oGreen, oAlpha, nRed, nBlue, nGreen, nAlpha: byte;

begin

    oAlpha := (OldColor shr AShift);

    nAlpha := (NewColor shr AShift);

    // shortcircuit

    if (oAlpha = 0) or (nAlpha = $FF) then

        begin

        addBgColor:= NewColor;

        exit

        end; 

    // Get colors

    oRed   := (OldColor shr RShift);

    oGreen := (OldColor shr GShift);

    oBlue  := (OldColor shr BShift);

    nRed   := (NewColor shr RShift);

    nGreen := (NewColor shr GShift);

    nBlue  := (NewColor shr BShift);

    // Mix colors

    nRed   := min(255,((nRed*nAlpha) div 255) + ((oRed*oAlpha*byte(255-nAlpha)) div 65025));

    nGreen := min(255,((nGreen*nAlpha) div 255) + ((oGreen*oAlpha*byte(255-nAlpha)) div 65025));

    nBlue  := min(255,((nBlue*nAlpha) div 255) + ((oBlue*oAlpha*byte(255-nAlpha)) div 65025)); 

    nAlpha := min(255, oAlpha + nAlpha);

    addBgColor := (nAlpha shl AShift) or (nRed shl RShift) or (nGreen shl GShift) or (nBlue shl BShift);

end;

procedure FillCircleLines(x, y, dx, dy: LongInt; Value: Longword);

var i: LongInt;

begin

if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[y + dy, i] and lfIndestructible) = 0 then

            Land[y + dy, i]:= Value;

if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[y - dy, i] and lfIndestructible) = 0 then

            Land[y - dy, i]:= Value;

if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[y + dx, i] and lfIndestructible) = 0 then

            Land[y + dx, i]:= Value;

if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[y - dx, i] and lfIndestructible) = 0 then

            Land[y - dx, i]:= Value;

end;

procedure ChangeCircleLines(x, y, dx, dy: LongInt; doSet: boolean);

var i: LongInt;

begin

if not doSet then

    begin

    if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if (Land[y + dy, i] > 0) and (Land[y + dy, i] < 256) then

                dec(Land[y + dy, i]); // check > 0 because explosion can erase collision data

    if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if (Land[y - dy, i] > 0) and (Land[y - dy, i] < 256) then

                dec(Land[y - dy, i]);

    if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if (Land[y + dx, i] > 0) and (Land[y + dx, i] < 256) then

                dec(Land[y + dx, i]);

    if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if (Land[y - dx, i] > 0) and (Land[y - dx, i] < 256) then

                dec(Land[y - dx, i]);

    end

else

    begin

    if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if (Land[y + dy, i] < 256) then

                inc(Land[y + dy, i]);

    if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

            if (Land[y - dy, i] < 256) then

                inc(Land[y - dy, i]);

    if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if (Land[y + dx, i] < 256) then

                inc(Land[y + dx, i]);

    if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

        for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

            if (Land[y - dx, i] < 256) then

                inc(Land[y - dx, i]);

    end

end;

procedure FillRoundInLand(X, Y, Radius: LongInt; Value: Longword);

var dx, dy, d: LongInt;

begin

dx:= 0;

dy:= Radius;

d:= 3 - 2 * Radius;

while (dx < dy) do

    begin

    FillCircleLines(x, y, dx, dy, Value);

    if (d < 0) then

        d:= d + 4 * dx + 6

    else

        begin

        d:= d + 4 * (dx - dy) + 10;

        dec(dy)

        end;

    inc(dx)

    end;

if (dx = dy) then

    FillCircleLines(x, y, dx, dy, Value);

end;

procedure ChangeRoundInLand(X, Y, Radius: LongInt; doSet: boolean);

var dx, dy, d: LongInt;

begin

dx:= 0;

dy:= Radius;

d:= 3 - 2 * Radius;

while (dx < dy) do

    begin

    ChangeCircleLines(x, y, dx, dy, doSet);

    if (d < 0) then

        d:= d + 4 * dx + 6

    else

        begin

        d:= d + 4 * (dx - dy) + 10;

        dec(dy)

        end;

    inc(dx)

    end;

if (dx = dy) then

    ChangeCircleLines(x, y, dx, dy, doSet)

end;

procedure FillLandCircleLines0(x, y, dx, dy: LongInt);

var i, t: LongInt;

begin

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfIndestructible) = 0) and (not disableLandBack or (Land[t, i] > 255))  then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

end;

function FillLandCircleLinesBG(x, y, dx, dy: LongInt): Longword;

var i, t, by, bx: LongInt;

    cnt: Longword;

begin

cnt:= 0;

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then 

                LandPixels[by, bx]:= 0

            end;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then 

                LandPixels[by, bx]:= 0

            end;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then 

                LandPixels[by, bx]:= 0

            end;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[t, i] and lfIndestructible) = 0 then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                begin

                by:= t; bx:= i;

                end

            else

                begin

                by:= t div 2; bx:= i div 2;

                end;

            if ((Land[t, i] and lfBasic) <> 0) and (((LandPixels[by,bx] and AMask) shr AShift) = 255) and (not disableLandBack) then

                begin

                inc(cnt);

                LandPixels[by, bx]:= LandBackPixel(i, t)

                end

            else if ((Land[t, i] and lfObject) <> 0) or (((LandPixels[by,bx] and AMask) shr AShift) < 255) then 

                LandPixels[by, bx]:= 0

            end;

FillLandCircleLinesBG:= cnt;

end;

procedure FillLandCircleLinesEBC(x, y, dx, dy: LongInt);

var i, t: LongInt;

begin

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= cExplosionBorderColor

            else

                LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

            Land[t, i]:= Land[t, i] or lfDamaged;

            //Despeckle(i, t);

            LandDirty[t div 32, i div 32]:= 1;

            end;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= cExplosionBorderColor

            else

                LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

            Land[t, i]:= Land[t, i] or lfDamaged;

            //Despeckle(i, t);

            LandDirty[t div 32, i div 32]:= 1;

            end;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= cExplosionBorderColor

            else

               LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

            Land[t, i]:= Land[t, i] or lfDamaged;

            //Despeckle(i, t);

            LandDirty[t div 32, i div 32]:= 1;

            end;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

            begin

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= cExplosionBorderColor

            else

                LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

            Land[t, i]:= Land[t, i] or lfDamaged;

            //Despeckle(i, y - dy);

            LandDirty[t div 32, i div 32]:= 1;

            end;

end;

function DrawExplosion(X, Y, Radius: LongInt): Longword;

var dx, dy, ty, tx, d: LongInt;

    cnt: Longword;

begin

// draw background land texture

    begin

    cnt:= 0;

    dx:= 0;

    dy:= Radius;

    d:= 3 - 2 * Radius;

    while (dx < dy) do

        begin

        inc(cnt, FillLandCircleLinesBG(x, y, dx, dy));

        if (d < 0) then

            d:= d + 4 * dx + 6

        else

            begin

            d:= d + 4 * (dx - dy) + 10;

            dec(dy)

            end;

        inc(dx)

        end;

    if (dx = dy) then

        inc(cnt, FillLandCircleLinesBG(x, y, dx, dy));

    end;

// draw a hole in land

if Radius > 20 then

    begin

    dx:= 0;

    dy:= Radius - 15;

    d:= 3 - 2 * dy;

    while (dx < dy) do

        begin

        FillLandCircleLines0(x, y, dx, dy);

        if (d < 0) then

            d:= d + 4 * dx + 6

        else

            begin

            d:= d + 4 * (dx - dy) + 10;

            dec(dy)

            end;

        inc(dx)

        end;

    if (dx = dy) then

        FillLandCircleLines0(x, y, dx, dy);

    end;

  // FillRoundInLand after erasing land pixels to allow Land 0 check for mask.png to function

    FillRoundInLand(X, Y, Radius, 0);

// draw explosion border

    begin

    inc(Radius, 4);

    dx:= 0;

    dy:= Radius;

    d:= 3 - 2 * Radius;

    while (dx < dy) do

        begin

        FillLandCircleLinesEBC(x, y, dx, dy);

        if (d < 0) then

            d:= d + 4 * dx + 6

        else

            begin

            d:= d + 4 * (dx - dy) + 10;

            dec(dy)

            end;

        inc(dx)

        end;

    if (dx = dy) then

        FillLandCircleLinesEBC(x, y, dx, dy);

    end;

tx:= Max(X - Radius - 1, 0);

dx:= Min(X + Radius + 1, LAND_WIDTH) - tx;

ty:= Max(Y - Radius - 1, 0);

dy:= Min(Y + Radius + 1, LAND_HEIGHT) - ty;

UpdateLandTexture(tx, dx, ty, dy);

DrawExplosion:= cnt

end;

procedure DrawHLinesExplosions(ar: PRangeArray; Radius: LongInt; y, dY: LongInt; Count: Byte);

var tx, ty, by, bx,  i: LongInt;

begin

for i:= 0 to Pred(Count) do

    begin

    for ty:= Max(y - Radius, 0) to Min(y + Radius, LAND_HEIGHT) do

        for tx:= Max(0, ar^[i].Left - Radius) to Min(LAND_WIDTH, ar^[i].Right + Radius) do

            begin

            if (Land[ty, tx] and lfIndestructible) = 0 then

                begin

                if (cReducedQuality and rqBlurryLand) = 0 then

                    begin

                    by:= ty; bx:= tx;

                    end

                else