(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2013 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA

 *)

(*

 * This file contains the step handlers for gears.

 *

 * Important: Since gears change the course of the game, calculations that

 *            lead to different results for different clients/players/machines

 *            should NOT occur!

 *            Use safe functions and data types! (e.g. GetRandom() and hwFloat)

 *)

 {$INCLUDE "options.inc"}

unit uGearsHandlersMess;

interface

uses uTypes, uFloat;

procedure doStepPerPixel(Gear: PGear; step: TGearStepProcedure; onlyCheckIfChanged: boolean);

procedure makeHogsWorry(x, y: hwFloat; r: LongInt);

procedure HideHog(HH: PHedgehog);

procedure doStepDrowningGear(Gear: PGear);

procedure doStepFallingGear(Gear: PGear);

procedure doStepBomb(Gear: PGear);

procedure doStepMolotov(Gear: PGear);

procedure doStepCluster(Gear: PGear);

procedure doStepShell(Gear: PGear);

procedure doStepSnowball(Gear: PGear);

procedure doStepSnowflake(Gear: PGear);

procedure doStepGrave(Gear: PGear);

procedure doStepBeeWork(Gear: PGear);

procedure doStepBee(Gear: PGear);

procedure doStepShotIdle(Gear: PGear);

procedure doStepShotgunShot(Gear: PGear);

procedure spawnBulletTrail(Bullet: PGear);

procedure doStepBulletWork(Gear: PGear);

procedure doStepDEagleShot(Gear: PGear);

procedure doStepSniperRifleShot(Gear: PGear);

procedure doStepActionTimer(Gear: PGear);

procedure doStepPickHammerWork(Gear: PGear);

procedure doStepPickHammer(Gear: PGear);

procedure doStepBlowTorchWork(Gear: PGear);

procedure doStepBlowTorch(Gear: PGear);

procedure doStepMine(Gear: PGear);

procedure doStepSMine(Gear: PGear);

procedure doStepDynamite(Gear: PGear);

procedure doStepRollingBarrel(Gear: PGear);

procedure doStepCase(Gear: PGear);

procedure doStepTarget(Gear: PGear);

procedure doStepIdle(Gear: PGear);

procedure doStepShover(Gear: PGear);

procedure doStepWhip(Gear: PGear);

procedure doStepFlame(Gear: PGear);

procedure doStepFirePunchWork(Gear: PGear);

procedure doStepFirePunch(Gear: PGear);

procedure doStepParachuteWork(Gear: PGear);

procedure doStepParachute(Gear: PGear);

procedure doStepAirAttackWork(Gear: PGear);

procedure doStepAirAttack(Gear: PGear);

procedure doStepAirBomb(Gear: PGear);

procedure doStepGirder(Gear: PGear);

procedure doStepTeleportAfter(Gear: PGear);

procedure doStepTeleportAnim(Gear: PGear);

procedure doStepTeleport(Gear: PGear);

procedure doStepSwitcherWork(Gear: PGear);

procedure doStepSwitcher(Gear: PGear);

procedure doStepMortar(Gear: PGear);

procedure doStepKamikazeWork(Gear: PGear);

procedure doStepKamikazeIdle(Gear: PGear);

procedure doStepKamikaze(Gear: PGear);

procedure doStepCakeExpl(Gear: PGear);

procedure doStepCakeDown(Gear: PGear);

procedure doStepCakeWork(Gear: PGear);

procedure doStepCakeUp(Gear: PGear);

procedure doStepCakeFall(Gear: PGear);

procedure doStepCake(Gear: PGear);

procedure doStepSeductionWork(Gear: PGear);

procedure doStepSeductionWear(Gear: PGear);

procedure doStepSeduction(Gear: PGear);

procedure doStepWaterUp(Gear: PGear);

procedure doStepDrillDrilling(Gear: PGear);

procedure doStepDrill(Gear: PGear);

procedure doStepBallgunWork(Gear: PGear);

procedure doStepBallgun(Gear: PGear);

procedure doStepRCPlaneWork(Gear: PGear);

procedure doStepRCPlane(Gear: PGear);

procedure doStepJetpackWork(Gear: PGear);

procedure doStepJetpack(Gear: PGear);

procedure doStepBirdyDisappear(Gear: PGear);

procedure doStepBirdyFly(Gear: PGear);

procedure doStepBirdyDescend(Gear: PGear);

procedure doStepBirdyAppear(Gear: PGear);

procedure doStepBirdy(Gear: PGear);

procedure doStepEggWork(Gear: PGear);

procedure doPortalColorSwitch();

procedure doStepPortal(Gear: PGear);

procedure loadNewPortalBall(oldPortal: PGear; destroyGear: Boolean);

procedure doStepMovingPortal_real(Gear: PGear);

procedure doStepMovingPortal(Gear: PGear);

procedure doStepPortalShot(newPortal: PGear);

procedure doStepPiano(Gear: PGear);

procedure doStepSineGunShotWork(Gear: PGear);

procedure doStepSineGunShot(Gear: PGear);

procedure doStepFlamethrowerWork(Gear: PGear);

procedure doStepFlamethrower(Gear: PGear);

procedure doStepLandGunWork(Gear: PGear);

procedure doStepLandGun(Gear: PGear);

procedure doStepPoisonCloud(Gear: PGear);

procedure doStepHammer(Gear: PGear);

procedure doStepHammerHitWork(Gear: PGear);

procedure doStepHammerHit(Gear: PGear);

procedure doStepResurrectorWork(Gear: PGear);

procedure doStepResurrector(Gear: PGear);

procedure doStepNapalmBomb(Gear: PGear);

procedure doStepStructure(Gear: PGear);

procedure doStepTardisWarp(Gear: PGear);

procedure doStepTardis(Gear: PGear);

procedure updateFuel(Gear: PGear);

procedure updateTarget(Gear:PGear; newX, newY:HWFloat);

procedure doStepIceGun(Gear: PGear);

procedure doStepAddAmmo(Gear: PGear);

procedure doStepGenericFaller(Gear: PGear);

procedure doStepCreeper(Gear: PGear);

procedure doStepKnife(Gear: PGear);

var

    upd: Longword;

    snowLeft,snowRight: LongInt;

implementation

uses uConsts, uVariables, uVisualGearsList, uRandom, uCollisions, uGearsList, uUtils, uSound

    , SDLh, uScript, uGearsHedgehog, uGearsUtils, uIO, uCaptions, uLandGraphics

    , uGearsHandlers, uTextures, uRenderUtils, uAmmos, uTeams, uLandTexture, uCommands

    , uStore, uAI, uStats;

procedure doStepPerPixel(Gear: PGear; step: TGearStepProcedure; onlyCheckIfChanged: boolean);

var

    dX, dY, sX, sY: hwFloat;

    i, steps: LongWord;

    caller: TGearStepProcedure;

begin

    dX:= Gear^.dX;

    dY:= Gear^.dY;

    steps:= max(abs(hwRound(Gear^.X+dX)-hwRound(Gear^.X)), abs(hwRound(Gear^.Y+dY)-hwRound(Gear^.Y)));

    // Gear is still on the same Pixel it was before

    if steps < 1 then

        begin

        if onlyCheckIfChanged then

            begin

            Gear^.X := Gear^.X + dX;

            Gear^.Y := Gear^.Y + dY;

            EXIT;

            end

        else

            steps := 1;

        end;

    if steps > 1 then

        begin

        sX:= dX / steps;

        sY:= dY / steps;

        end

    else

        begin

        sX:= dX;

        sY:= dY;

        end;

    caller:= Gear^.doStep;

    for i:= 1 to steps do

        begin

        Gear^.X := Gear^.X + sX;

        Gear^.Y := Gear^.Y + sY;

        step(Gear);

        if (Gear^.doStep <> caller)

        or ((Gear^.State and gstCollision) <> 0)

        or ((Gear^.State and gstMoving) = 0) then

            break;

        end;

end;

procedure makeHogsWorry(x, y: hwFloat; r: LongInt);

var

    gi: PGear;

    d: LongInt;

begin

    gi := GearsList;

    while gi <> nil do

        begin

        if (gi^.Kind = gtHedgehog) then

            begin

            d := r - hwRound(Distance(gi^.X - x, gi^.Y - y));

            if (d > 1) and (not gi^.Invulnerable) and (GetRandom(2) = 0) then

                begin

                if (CurrentHedgehog^.Gear = gi) then

                    PlaySoundV(sndOops, gi^.Hedgehog^.Team^.voicepack)

                else

                    begin

                    if ((gi^.State and gstMoving) = 0) and (gi^.Hedgehog^.Effects[heFrozen] = 0) then

                        begin

                        gi^.dX.isNegative:= X<gi^.X;

                        gi^.State := gi^.State or gstLoser;

                        end;

                    if d > r div 2 then

                        PlaySoundV(sndNooo, gi^.Hedgehog^.Team^.voicepack)

                    else

                        PlaySoundV(sndUhOh, gi^.Hedgehog^.Team^.voicepack);

                    end;

                end;

            end;

        gi := gi^.NextGear

        end;

end;

procedure HideHog(HH: PHedgehog);

begin

    ScriptCall('onHogHide', HH^.Gear^.Uid);

    DeleteCI(HH^.Gear);

    if FollowGear = HH^.Gear then

        FollowGear:= nil;

    if lastGearByUID = HH^.Gear then

        lastGearByUID := nil;

    HH^.Gear^.Message:= HH^.Gear^.Message or gmRemoveFromList;

    with HH^.Gear^ do

        begin

        Z := cHHZ;

        HH^.Gear^.Active:= false;

        State:= State and (not (gstHHDriven or gstAttacking or gstAttacked));

        Message := Message and (not gmAttack);

    end;

    HH^.GearHidden:= HH^.Gear;

    HH^.Gear:= nil

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepDrowningGear(Gear: PGear);

    begin

    AllInactive := false;

    Gear^.Y := Gear^.Y + cDrownSpeed;

    Gear^.X := Gear^.X + Gear^.dX * cDrownSpeed;

    // Create some bubbles (0.5% might be better but causes too few bubbles sometimes)

    if ((not SuddenDeathDmg and (WaterOpacity < $FF))

    or (SuddenDeathDmg and (SDWaterOpacity < $FF))) and ((GameTicks and $1F) = 0) then

        if (Gear^.Kind = gtHedgehog) and (Random(4) = 0) then

            AddVisualGear(hwRound(Gear^.X) - Gear^.Radius, hwRound(Gear^.Y) - Gear^.Radius, vgtBubble)

    else if Random(12) = 0 then

             AddVisualGear(hwRound(Gear^.X) - Gear^.Radius, hwRound(Gear^.Y) - Gear^.Radius, vgtBubble);

    if (not SuddenDeathDmg and (WaterOpacity > $FE))

    or (SuddenDeathDmg and (SDWaterOpacity > $FE))

    or (hwRound(Gear^.Y) > Gear^.Radius + cWaterLine + cVisibleWater) then

        DeleteGear(Gear);

    end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepFallingGear(Gear: PGear);

var

    isFalling: boolean;

    //tmp: QWord;

    tX, tdX, tdY: hwFloat;

    collV, collH: LongInt;

    land: word;

begin

    tX:= Gear^.X;

      (TestCollisionXwithGear(Gear, 1) or TestCollisionXwithGear(Gear, -1))  then

        begin

        Gear^.X:= tX;

        Gear^.dX.isNegative:= (hwRound(tX) > leftX+Gear^.Radius*2)

        end;

    // clip velocity at 2 - over 1 per pixel, but really shouldn't cause many actual problems.

    if Gear^.dX.Round > 2 then

        Gear^.dX.QWordValue:= 8589934592;

    if Gear^.dY.Round > 2 then

        Gear^.dY.QWordValue:= 8589934592;

    if (Gear^.State and gstSubmersible <> 0) and (hwRound(Gear^.Y) > cWaterLine) then

        begin

        Gear^.dX:= Gear^.dX * _0_999;

        Gear^.dY:= Gear^.dY * _0_999

        end;

    Gear^.State := Gear^.State and (not gstCollision);

    collV := 0;

    collH := 0;

    tdX := Gear^.dX;

    tdY := Gear^.dY;

// might need some testing/adjustments - just to avoid projectiles to fly forever (accelerated by wind/skips)

    if (hwRound(Gear^.X) < min(LAND_WIDTH div -2, -2048))

    or (hwRound(Gear^.X) > max(LAND_WIDTH * 3 div 2, 6144)) then

        Gear^.State := Gear^.State or gstCollision;

    if Gear^.dY.isNegative then

        begin

        isFalling := true;

        land:= TestCollisionYwithGear(Gear, -1);

        if land <> 0 then

            begin

            collV := -1;

            if land and lfIce <> 0 then

                Gear^.dX := Gear^.dX * (_0_9 + Gear^.Friction * _0_1)

            else

                Gear^.dX := Gear^.dX * Gear^.Friction;

            Gear^.dY := - Gear^.dY * Gear^.Elasticity;

            Gear^.State := Gear^.State or gstCollision

            end

        else if (Gear^.AdvBounce=1) and (TestCollisionYwithGear(Gear, 1) <> 0) then

            collV := 1;

        end

    else

        begin // Gear^.dY.isNegative is false

        land:= TestCollisionYwithGear(Gear, 1);

        if land <> 0 then

            begin

            collV := 1;

            isFalling := false;

            if land and lfIce <> 0 then

                Gear^.dX := Gear^.dX * (_0_9 + Gear^.Friction * _0_1)

            else

                Gear^.dX := Gear^.dX * Gear^.Friction;

            Gear^.dY := - Gear^.dY * Gear^.Elasticity;

            Gear^.State := Gear^.State or gstCollision

            end

        else

            begin

            isFalling := true;

            if (Gear^.AdvBounce=1) and (TestCollisionYwithGear(Gear, -1) <> 0) then

                collV := -1

            end

        end;

    if TestCollisionXwithGear(Gear, hwSign(Gear^.dX)) then

        begin

        collH := hwSign(Gear^.dX);

        Gear^.dX := - Gear^.dX * Gear^.Elasticity;

        Gear^.dY :=   Gear^.dY * Gear^.Elasticity;

        Gear^.State := Gear^.State or gstCollision

        end

    else if (Gear^.AdvBounce=1) and TestCollisionXwithGear(Gear, -hwSign(Gear^.dX)) then

        collH := -hwSign(Gear^.dX);

    //if Gear^.AdvBounce and (collV <>0) and (collH <> 0) and (hwSqr(tdX) + hwSqr(tdY) > _0_08) then

    if (Gear^.AdvBounce=1) and (collV <>0) and (collH <> 0) and ((collV=-1)

    or ((tdX.QWordValue + tdY.QWordValue) > _0_2.QWordValue)) then

        begin

        Gear^.dX := tdY*Gear^.Elasticity*Gear^.Friction;

        Gear^.dY := tdX*Gear^.Elasticity;

        //*Gear^.Friction;

        Gear^.dY.isNegative := not tdY.isNegative;

        isFalling := false;

        Gear^.AdvBounce := 10;

        end;

    if Gear^.AdvBounce > 1 then

        dec(Gear^.AdvBounce);

    if isFalling then

        begin

        Gear^.dY := Gear^.dY + cGravity;

        if (GameFlags and gfMoreWind) <> 0 then

            Gear^.dX := Gear^.dX + cWindSpeed / Gear^.Density

            end;

    Gear^.X := Gear^.X + Gear^.dX;

    Gear^.Y := Gear^.Y + Gear^.dY;

    CheckGearDrowning(Gear);

    //if (hwSqr(Gear^.dX) + hwSqr(Gear^.dY) < _0_0002) and

    if (not isFalling) and ((Gear^.dX.QWordValue + Gear^.dY.QWordValue) < _0_02.QWordValue) then

        Gear^.State := Gear^.State and (not gstMoving)

    else

        Gear^.State := Gear^.State or gstMoving;

    if (Gear^.nImpactSounds > 0) and

        (Gear^.State and gstCollision <> 0) and

        (((Gear^.Kind <> gtMine) and (Gear^.Damage <> 0)) or (Gear^.State and gstMoving <> 0)) and

        (((Gear^.Radius < 3) and (Gear^.dY < -_0_1)) or

            ((Gear^.Radius >= 3) and

                ((Gear^.dX.QWordValue > _0_1.QWordValue) or (Gear^.dY.QWordValue > _0_1.QWordValue)))) then

        PlaySound(TSound(ord(Gear^.ImpactSound) + LongInt(GetRandom(Gear^.nImpactSounds))), true);

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepBomb(Gear: PGear);

var

    i, x, y: LongInt;

    dX, dY, gdX: hwFloat;

    vg: PVisualGear;

begin

    AllInactive := false;

    doStepFallingGear(Gear);

    dec(Gear^.Timer);

    if Gear^.Timer = 1000 then // might need adjustments

        case Gear^.Kind of

            gtGrenade: makeHogsWorry(Gear^.X, Gear^.Y, 50);

            gtClusterBomb: makeHogsWorry(Gear^.X, Gear^.Y, 20);

            gtWatermelon: makeHogsWorry(Gear^.X, Gear^.Y, 75);

            gtHellishBomb: makeHogsWorry(Gear^.X, Gear^.Y, 90);

            gtGasBomb: makeHogsWorry(Gear^.X, Gear^.Y, 50);

        end;

    if (Gear^.Kind = gtBall) and ((Gear^.State and gstTmpFlag) <> 0) then

        begin

        CheckCollision(Gear);

        if (Gear^.State and gstCollision) <> 0 then

            doMakeExplosion(hwRound(Gear^.X), hwRound(Gear^.Y), 20, Gear^.Hedgehog, EXPLDontDraw or EXPLNoGfx);

        end;

    if (Gear^.Kind = gtGasBomb) and ((GameTicks mod 200) = 0) then

        begin

        vg:= AddVisualGear(hwRound(Gear^.X), hwRound(Gear^.Y), vgtSmokeWhite);

        if vg <> nil then

            vg^.Tint:= $FFC0C000;

        end;

    if Gear^.Timer = 0 then

        begin

        case Gear^.Kind of

            gtGrenade: doMakeExplosion(hwRound(Gear^.X), hwRound(Gear^.Y), 50, Gear^.Hedgehog, EXPLAutoSound);

            gtBall: doMakeExplosion(hwRound(Gear^.X), hwRound(Gear^.Y), 40, Gear^.Hedgehog, EXPLAutoSound);

            gtClusterBomb:

                begin

                x := hwRound(Gear^.X);

                y := hwRound(Gear^.Y);

                gdX:= Gear^.dX;

                doMakeExplosion(x, y, 20, Gear^.Hedgehog, EXPLAutoSound);

                for i:= 0 to 4 do

                    begin

                    dX := rndSign(GetRandomf * _0_1) + gdX / 5;

                    dY := (GetRandomf - _3) * _0_08;

                    FollowGear := AddGear(x, y, gtCluster, 0, dX, dY, 25)

                    end

                end;

            gtWatermelon:

                begin

                x := hwRound(Gear^.X);

                y := hwRound(Gear^.Y);

                gdX:= Gear^.dX;

                doMakeExplosion(x, y, 75, Gear^.Hedgehog, EXPLAutoSound);

                for i:= 0 to 5 do

                    begin

                    dX := rndSign(GetRandomf * _0_1) + gdX / 5;

                    dY := (GetRandomf - _1_5) * _0_3;

                    FollowGear:= AddGear(x, y, gtMelonPiece, 0, dX, dY, 75);

                    FollowGear^.DirAngle := i * 60

                    end

                end;

            gtHellishBomb:

                begin

                x := hwRound(Gear^.X);

                y := hwRound(Gear^.Y);

                doMakeExplosion(x, y, 90, Gear^.Hedgehog, EXPLAutoSound);