(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2015 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uWorld;

interface

uses SDLh, uGears, uConsts, uFloat, uRandom, uTypes, uRenderUtils;

procedure initModule;

procedure freeModule;

procedure InitWorld;

procedure ResetWorldTex;

procedure DrawWorld(Lag: LongInt);

procedure DrawWorldStereo(Lag: LongInt; RM: TRenderMode);

procedure ShowMission(caption, subcaption, text: ansistring; icon, time : LongInt);

procedure HideMission;

procedure SetAmmoTexts(ammoType: TAmmoType; name: ansistring; caption: ansistring; description: ansistring);

procedure ShakeCamera(amount: LongInt);

procedure InitCameraBorders;

procedure InitTouchInterface;

procedure SetUtilityWidgetState(ammoType: TAmmoType);

procedure animateWidget(widget: POnScreenWidget; fade, showWidget: boolean);

procedure MoveCamera;

procedure onFocusStateChanged;

procedure updateCursorVisibility;

implementation

uses

    uStore

    , uMisc

    , uIO

    , uLocale

    , uSound

    , uAmmos

    , uVisualGears

    , uChat

    , uLandTexture

    , uVariables

    , uUtils

    , uTextures

    , uRender

    , uCaptions

    , uCursor

    , uCommands

    , uTeams

    , uDebug

{$IFDEF USE_VIDEO_RECORDING}

    , uVideoRec

{$ENDIF}

    ;

var AMShiftTargetX, AMShiftTargetY, AMShiftX, AMShiftY, SlotsNum: LongInt;

    AMAnimStartTime, AMState : LongInt;

    AMAnimState: Single;

    tmpSurface: PSDL_Surface;

    fpsTexture: PTexture;

    timeTexture: PTexture;

    FPS: Longword;

    CountTicks: Longword;

    prevPoint{, prevTargetPoint}: TPoint;

    amSel: TAmmoType = amNothing;

    missionTex: PTexture;

    missionTimer: LongInt;

    isFirstFrame: boolean;

    AMAnimType: LongInt;

    recTexture: PTexture;

    AmmoMenuTex     : PTexture;

    HorizontOffset: LongInt;

    cOffsetY: LongInt;

    WorldEnd, WorldFade : array[0..3] of HwColor4f;

const cStereo_Sky           = 0.0500;

      cStereo_Horizon       = 0.0250;

      cStereo_MidDistance   = 0.0175;

      cStereo_Water_distant = 0.0125;

      cStereo_Land          = 0.0075;

      cStereo_Water_near    = 0.0025;

      cStereo_Outside       = -0.0400;

      AMAnimDuration = 200;

      AMHidden    = 0;//AMState values

      AMShowingUp = 1;

      AMShowing   = 2;

      AMHiding    = 3;

      AMTypeMaskX     = $00000001;

      AMTypeMaskY     = $00000002;

      AMTypeMaskAlpha = $00000004;

      //AMTypeMaskSlide = $00000008;

{$IFDEF MOBILE}

      AMSlotSize = 48;

{$ELSE}

      AMSlotSize = 32;

{$ENDIF}

      AMSlotPadding = (AMSlotSize - 32) shr 1;

      cSendCursorPosTime = 50;

      cCursorEdgesDist   = 100;

// helper functions to create the goal/game mode string

function AddGoal(s: ansistring; gf: longword; si: TGoalStrId; i: LongInt): ansistring;

var t: ansistring;

begin

{$IFNDEF PAS2C}

    if (GameFlags and gf) <> 0 then

        begin

        t:= inttostr(i);

        s:= s + FormatA(trgoal[si], t) + '|'

        end;

{$ENDIF}

    AddGoal:= s;

end;

function AddGoal(s: ansistring; gf: longword; si: TGoalStrId): ansistring;

begin

{$IFNDEF PAS2C}

    if (GameFlags and gf) <> 0 then

        s:= s + trgoal[si] + '|';

{$ENDIF}

    AddGoal:= s;

end;

procedure InitWorld;

var i, t: LongInt;

    cp: PClan;

    g: ansistring;

begin

missionTimer:= 0;

if (GameFlags and gfRandomOrder) <> 0 then  // shuffle them up a bit

    begin

    for i:= 0 to ClansCount * 4 do

        begin

        t:= GetRandom(ClansCount);

        if t <> 0 then

            begin

            cp:= ClansArray[0];

            ClansArray[0]:= ClansArray[t];

            ClansArray[t]:= cp;

            ClansArray[t]^.ClanIndex:= t;

            ClansArray[0]^.ClanIndex:= 0;

            if (LocalClan = t) then

                LocalClan:= 0

            else if (LocalClan = 0) then

                LocalClan:= t

            end;

        end;

    CurrentTeam:= ClansArray[0]^.Teams[0];

    end;

// if special game flags/settings are changed, add them to the game mode notice window and then show it

g:= ''; // no text/things to note yet

// add custom goals from lua script if there are any

if LuaGoals <> ansistring('') then

    g:= LuaGoals + '|';

// check different game flags

g:= AddGoal(g, gfPlaceHog, gidPlaceHog); // placement?

g:= AddGoal(g, gfKing, gidKing); // king?

if ((GameFlags and gfKing) <> 0) and ((GameFlags and gfPlaceHog) = 0) then

    g:= AddGoal(g, gfAny, gidPlaceKing);

g:= AddGoal(g, gfTagTeam, gidTagTeam); // tag team mode?

g:= AddGoal(g, gfSharedAmmo, gidSharedAmmo); // shared ammo?

g:= AddGoal(g, gfPerHogAmmo, gidPerHogAmmo);

g:= AddGoal(g, gfMoreWind, gidMoreWind);

g:= AddGoal(g, gfLowGravity, gidLowGravity); // low gravity?

g:= AddGoal(g, gfSolidLand, gidSolidLand); // solid land?

g:= AddGoal(g, gfArtillery, gidArtillery); // artillery?

g:= AddGoal(g, gfInfAttack, gidInfAttack);

g:= AddGoal(g, gfResetWeps, gidResetWeps);

g:= AddGoal(g, gfResetHealth, gidResetHealth);

g:= AddGoal(g, gfKarma, gidKarma); // karma?

g:= AddGoal(g, gfVampiric, gidVampiric); // vampirism?

g:= AddGoal(g, gfInvulnerable, gidInvulnerable); // invulnerability?

g:= AddGoal(g, gfAISurvival, gidAISurvival);

// modified damage modificator?

if cDamagePercent <> 100 then

    g:= AddGoal(g, gfAny, gidDamageModifier, cDamagePercent);

// fade in

ScreenFade:= sfFromBlack;

ScreenFadeValue:= sfMax;

ScreenFadeSpeed:= 1;

// modified mine timers?

if cMinesTime <> 3000 then

    begin

    if cMinesTime = 0 then

        g:= AddGoal(g, gfAny, gidNoMineTimer)

    else if cMinesTime < 0 then

        g:= AddGoal(g, gfAny, gidRandomMineTimer)

    else

        g:= AddGoal(g, gfAny, gidMineTimer, cMinesTime div 1000);

    end;

// if the string has been set, show it for (default timeframe) seconds

if length(g) > 0 then

    ShowMission(trgoal[gidCaption], trgoal[gidSubCaption], g, 1, 0);

//cWaveWidth:= SpritesData[sprWater].Width;

//cWaveHeight:= SpritesData[sprWater].Height;

cWaveHeight:= 32;

InitCameraBorders();

uCursor.init();

prevPoint.X:= 0;

prevPoint.Y:= cScreenHeight div 2;

//prevTargetPoint.X:= 0;

//prevTargetPoint.Y:= 0;

WorldDx:=  -(LongInt(leftX + (playWidth div 2))); // -(LAND_WIDTH div 2);// + cScreenWidth div 2;

WorldDy:=  -(LAND_HEIGHT - (playHeight div 2)) + (cScreenHeight div 2);

//aligns it to the bottom of the screen, minus the border

SkyOffset:= 0;

HorizontOffset:= 0;

InitTouchInterface();

AMAnimType:= AMTypeMaskX or AMTypeMaskAlpha;

end;

procedure InitCameraBorders;

begin

cGearScrEdgesDist:= min(2 * cScreenHeight div 5, 2 * cScreenWidth div 5);

end;

procedure InitTouchInterface;

begin

{$IFDEF USE_TOUCH_INTERFACE}

//positioning of the buttons

buttonScale:= 1 / cDefaultZoomLevel;

with JumpWidget do

    begin

    show:= true;

    sprite:= sprJumpWidget;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= (cScreenWidth shr 1) - Round(frame.w * 1.2);

    frame.y:= cScreenHeight - frame.h * 2;

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    end;

with AMWidget do

    begin

    show:= true;

    sprite:= sprAMWidget;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= (cScreenWidth shr 1) - frame.w * 2;

    frame.y:= cScreenHeight - Round(frame.h * 1.2);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    end;

with arrowLeft do

    begin

    show:= true;

    sprite:= sprArrowLeft;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= -(cScreenWidth shr 1) + Round(frame.w * 0.25);

    frame.y:= cScreenHeight - Round(frame.h * 1.5);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    end;

with arrowRight do

    begin

    show:= true;

    sprite:= sprArrowRight;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= -(cScreenWidth shr 1) + Round(frame.w * 1.5);

    frame.y:= cScreenHeight - Round(frame.h * 1.5);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    end;

with firebutton do

    begin

    show:= true;

    sprite:= sprFireButton;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= arrowRight.frame.x + arrowRight.frame.w;

    frame.y:= arrowRight.frame.y + (arrowRight.frame.w shr 1) - (frame.w shr 1);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    end;

with arrowUp do

    begin

    show:= false;

    sprite:= sprArrowUp;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= (cScreenWidth shr 1) - frame.w * 2;

    frame.y:= jumpWidget.frame.y - Round(frame.h * 1.25);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    with moveAnim do

         begin

         target.x:= frame.x;

         target.y:= frame.y;

         source.x:= frame.x - Round(frame.w * 0.75);

         source.y:= frame.y;

         end;

    end;

with arrowDown do

    begin

    show:= false;

    sprite:= sprArrowDown;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= (cScreenWidth shr 1) - frame.w * 2;

    frame.y:= jumpWidget.frame.y - Round(frame.h * 1.25);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    with moveAnim do

        begin

        target.x:= frame.x;

        target.y:= frame.y;

        source.x:= frame.x + Round(frame.w * 0.75);

        source.y:= frame.y;

        end;

    end;

with pauseButton do

    begin

    show:= true;

    sprite:= sprPauseButton;

    frame.w:= Round(spritesData[sprPauseButton].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprPauseButton].Texture^.h * buttonScale);

    frame.x:= cScreenWidth div 2 - frame.w;

    frame.y:= 0;

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    end;

with utilityWidget do

    begin

    show:= false;

    sprite:= sprTimerButton;

    frame.w:= Round(spritesData[sprite].Texture^.w * buttonScale);

    frame.h:= Round(spritesData[sprite].Texture^.h * buttonScale);

    frame.x:= arrowLeft.frame.x;

    frame.y:= arrowLeft.frame.y - Round(frame.h * 1.25);

    active.x:= frame.x;

    active.y:= frame.y;

    active.w:= frame.w;

    active.h:= frame.h;

    with moveAnim do

        begin

        target.x:= frame.x;

        target.y:= frame.y;

        source.x:= frame.x;

        source.y:= frame.y;

        end;

    end;

{$ENDIF}

end;

// for uStore texture resetting

procedure ResetWorldTex;

begin

    FreeAndNilTexture(fpsTexture);

    FreeAndNilTexture(timeTexture);

    FreeAndNilTexture(missionTex);

    FreeAndNilTexture(recTexture);

    FreeAndNilTexture(AmmoMenuTex);

    AmmoMenuInvalidated:= true;

end;

function GetAmmoMenuTexture(Ammo: PHHAmmo): PTexture;

const BORDERSIZE = 2;

var x, y, i, t, SlotsNumY, SlotsNumX, AMFrame: LongInt;

    STurns: LongInt;

    amSurface: PSDL_Surface;

    AMRect: TSDL_Rect;

{$IFDEF USE_AM_NUMCOLUMN}tmpsurf: PSDL_Surface;{$ENDIF}

begin

    if cOnlyStats then exit(nil);

    SlotsNum:= 0;

    for i:= 0 to cMaxSlotIndex do

        if (i <> cHiddenSlotIndex) and (Ammo^[i, 0].Count > 0) then

            inc(SlotsNum);

{$IFDEF USE_LANDSCAPE_AMMOMENU}

    SlotsNumX:= SlotsNum;

    SlotsNumY:= cMaxSlotAmmoIndex + 2;

    {$IFDEF USE_AM_NUMCOLUMN}

    inc(SlotsNumY);

    {$ENDIF}

{$ELSE}

    SlotsNumX:= cMaxSlotAmmoIndex + 1;

    SlotsNumY:= SlotsNum + 1;

    {$IFDEF USE_AM_NUMCOLUMN}

    inc(SlotsNumX);

    {$ENDIF}

{$ENDIF}

    AmmoRect.w:= (BORDERSIZE*2) + (SlotsNumX * AMSlotSize) + (SlotsNumX-1);

    AmmoRect.h:= (BORDERSIZE*2) + (SlotsNumY * AMSlotSize) + (SlotsNumY-1);

    amSurface := SDL_CreateRGBSurface(SDL_SWSURFACE, AmmoRect.w, AmmoRect.h, 32, RMask, GMask, BMask, AMask);

    AMRect.x:= BORDERSIZE;

    AMRect.y:= BORDERSIZE;

    AMRect.w:= AmmoRect.w - (BORDERSIZE*2);

    AMRect.h:= AmmoRect.h - (BORDERSIZE*2);

    SDL_FillRect(amSurface, @AMRect, SDL_MapRGB(amSurface^.format, 0,0,0));

    x:= AMRect.x;

    y:= AMRect.y;

    for i:= 0 to cMaxSlotIndex do

        if (i <> cHiddenSlotIndex) and (Ammo^[i, 0].Count > 0) then

            begin

{$IFDEF USE_LANDSCAPE_AMMOMENU}

            y:= AMRect.y;

{$ELSE}

            x:= AMRect.x;

{$ENDIF}

{$IFDEF USE_AM_NUMCOLUMN}

            tmpsurf:= TTF_RenderUTF8_Blended(Fontz[fnt16].Handle, Str2PChar('F' + IntToStr(i+1)), cWhiteColorChannels);

            copyToXY(tmpsurf, amSurface,

                     x + AMSlotPadding + (AMSlotSize shr 1) - (tmpsurf^.w shr 1),

                     y + AMSlotPadding + (AMSlotSize shr 1) - (tmpsurf^.h shr 1));

            SDL_FreeSurface(tmpsurf);

    {$IFDEF USE_LANDSCAPE_AMMOMENU}

            y:= AMRect.y + AMSlotSize + 1;

    {$ELSE}

            x:= AMRect.x + AMSlotSize + 1;

    {$ENDIF}

{$ENDIF}

            for t:=0 to cMaxSlotAmmoIndex do