(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2011 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA

 *)

{$INCLUDE "options.inc"}

unit uLandGraphics;

interface

uses uFloat, uConsts, uTypes;

type PRangeArray = ^TRangeArray;

     TRangeArray = array[0..31] of record

                                   Left, Right: LongInt;

                                   end;

function  addBgColor(OldColor, NewColor: LongWord): LongWord;

function  SweepDirty: boolean;

function  Despeckle(X, Y: LongInt): boolean;

function  CheckLandValue(X, Y: LongInt; LandFlag: Word): boolean;

function  DrawExplosion(X, Y, Radius: LongInt): Longword;

procedure DrawHLinesExplosions(ar: PRangeArray; Radius: LongInt; y, dY: LongInt; Count: Byte);

procedure DrawTunnel(X, Y, dX, dY: hwFloat; ticks, HalfWidth: LongInt);

procedure FillRoundInLand(X, Y, Radius: LongInt; Value: Longword);

procedure ChangeRoundInLand(X, Y, Radius: LongInt; doSet: boolean);

function  LandBackPixel(x, y: LongInt): LongWord;

function TryPlaceOnLand(cpX, cpY: LongInt; Obj: TSprite; Frame: LongInt; doPlace: boolean; indestructible: boolean): boolean;

implementation

uses SDLh, uLandTexture, uVariables, uUtils, uDebug;

function addBgColor(OldColor, NewColor: LongWord): LongWord;

// Factor ranges from 0 to 100% NewColor

var

    oRed, oBlue, oGreen, oAlpha, nRed, nBlue, nGreen, nAlpha: Byte;

begin

    // Get colors

    oAlpha := (OldColor shr AShift) and $FF;

    oRed   := (OldColor shr RShift) and $FF;

    oGreen := (OldColor shr GShift) and $FF;

    oBlue  := (OldColor shr BShift) and $FF;

    nAlpha := (NewColor shr AShift) and $FF;

    nRed   := (NewColor shr RShift) and $FF;

    nGreen := (NewColor shr GShift) and $FF;

    nBlue  := (NewColor shr BShift) and $FF;

    // Mix colors

    nAlpha := min(255, oAlpha + nAlpha);

    nRed   := ((oRed * oAlpha) + (nRed * (255-oAlpha))) div 255;

    nGreen := ((oGreen * oAlpha) + (nGreen * (255-oAlpha))) div 255;

    nBlue  := ((oBlue * oAlpha) + (nBlue * (255-oAlpha))) div 255;

    addBgColor := (nAlpha shl AShift) or (nRed shl RShift) or (nGreen shl GShift) or (nBlue shl BShift);

end;

procedure FillCircleLines(x, y, dx, dy: LongInt; Value: Longword);

var i: LongInt;

begin

if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[y + dy, i] and lfIndestructible) = 0 then

            Land[y + dy, i]:= Value;

if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (Land[y - dy, i] and lfIndestructible) = 0 then

            Land[y - dy, i]:= Value;

if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[y + dx, i] and lfIndestructible) = 0 then

            Land[y + dx, i]:= Value;

if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (Land[y - dx, i] and lfIndestructible) = 0 then

            Land[y - dx, i]:= Value;

end;

procedure ChangeCircleLines(x, y, dx, dy: LongInt; doSet: boolean);

var i: LongInt;

begin

if not doSet then

   begin

   if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

          if (Land[y + dy, i] > 0) and (Land[y + dy, i] < 256) then dec(Land[y + dy, i]); // check > 0 because explosion can erase collision data

   if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

          if (Land[y - dy, i] > 0) and (Land[y - dy, i] < 256) then dec(Land[y - dy, i]);

   if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

          if (Land[y + dx, i] > 0) and (Land[y + dx, i] < 256) then dec(Land[y + dx, i]);

   if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

          if (Land[y - dx, i] > 0) and (Land[y - dx, i] < 256) then dec(Land[y - dx, i]);

   end else

   begin

   if ((y + dy) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

          if (Land[y + dy, i] < 256) then

              inc(Land[y + dy, i]);

   if ((y - dy) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

          if (Land[y - dy, i] < 256) then

              inc(Land[y - dy, i]);

   if ((y + dx) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

          if (Land[y + dx, i] < 256) then

              inc(Land[y + dx, i]);

   if ((y - dx) and LAND_HEIGHT_MASK) = 0 then

      for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

          if (Land[y - dx, i] < 256) then

              inc(Land[y - dx, i]);

   end

end;

procedure FillRoundInLand(X, Y, Radius: LongInt; Value: Longword);

var dx, dy, d: LongInt;

begin

  dx:= 0;

  dy:= Radius;

  d:= 3 - 2 * Radius;

  while (dx < dy) do

     begin

     FillCircleLines(x, y, dx, dy, Value);

     if (d < 0)

     then d:= d + 4 * dx + 6

     else begin

          d:= d + 4 * (dx - dy) + 10;

          dec(dy)

          end;

     inc(dx)

     end;

  if (dx = dy) then FillCircleLines(x, y, dx, dy, Value);

end;

procedure ChangeRoundInLand(X, Y, Radius: LongInt; doSet: boolean);

var dx, dy, d: LongInt;

begin

  dx:= 0;

  dy:= Radius;

  d:= 3 - 2 * Radius;

  while (dx < dy) do

     begin

     ChangeCircleLines(x, y, dx, dy, doSet);

     if (d < 0)

     then d:= d + 4 * dx + 6

     else begin

          d:= d + 4 * (dx - dy) + 10;

          dec(dy)

          end;

     inc(dx)

     end;

  if (dx = dy) then ChangeCircleLines(x, y, dx, dy, doSet)

end;

procedure FillLandCircleLines0(x, y, dx, dy: LongInt);

var i, t: LongInt;

begin

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (not isMap and ((Land[t, i] and lfIndestructible) = 0)) or ((Land[t, i] and lfBasic) <> 0) then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

        if (not isMap and ((Land[t, i] and lfIndestructible) = 0)) or ((Land[t, i] and lfBasic) <> 0) then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (not isMap and ((Land[t, i] and lfIndestructible) = 0)) or ((Land[t, i] and lfBasic) <> 0) then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

    for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

        if (not isMap and ((Land[t, i] and lfIndestructible) = 0)) or ((Land[t, i] and lfBasic) <> 0) then

            if (cReducedQuality and rqBlurryLand) = 0 then

                LandPixels[t, i]:= 0

            else

                LandPixels[t div 2, i div 2]:= 0;

end;

function FillLandCircleLinesBG(x, y, dx, dy: LongInt): Longword;

var i, t: LongInt;

    cnt: Longword;

begin

cnt:= 0;

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) and not disableLandBack then

           begin

           inc(cnt);

           if (cReducedQuality and rqBlurryLand) = 0 then

               LandPixels[t, i]:= LandBackPixel(i, t)

           else

               LandPixels[t div 2, i div 2]:= LandBackPixel(i, t)

           end

       else

           if ((Land[t, i] and lfObject) <> 0) or (disableLandBack and ((Land[t, i] and lfIndestructible) = 0)) then

               if (cReducedQuality and rqBlurryLand) = 0 then

                   LandPixels[t, i]:= 0

               else

                   LandPixels[t div 2, i div 2]:= 0;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) and not disableLandBack then

           begin

           inc(cnt);

           if (cReducedQuality and rqBlurryLand) = 0 then

               LandPixels[t, i]:= LandBackPixel(i, t)

           else

               LandPixels[t div 2, i div 2]:= LandBackPixel(i, t)

           end

       else

           if ((Land[t, i] and lfObject) <> 0) or (disableLandBack and ((Land[t, i] and lfIndestructible) = 0)) then

               if (cReducedQuality and rqBlurryLand) = 0 then

                   LandPixels[t, i]:= 0

               else

                   LandPixels[t div 2, i div 2]:= 0;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) and not disableLandBack then

           begin

           inc(cnt);

           if (cReducedQuality and rqBlurryLand) = 0 then

               LandPixels[t, i]:= LandBackPixel(i, t)

           else

               LandPixels[t div 2, i div 2]:= LandBackPixel(i, t)

           end

       else

           if ((Land[t, i] and lfObject) <> 0) or (disableLandBack and ((Land[t, i] and lfIndestructible) = 0)) then

               if (cReducedQuality and rqBlurryLand) = 0 then

                   LandPixels[t, i]:= 0

               else

                   LandPixels[t div 2, i div 2]:= 0;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) and not disableLandBack then

           begin

           inc(cnt);

           if (cReducedQuality and rqBlurryLand) = 0 then

               LandPixels[t, i]:= LandBackPixel(i, t)

           else

               LandPixels[t div 2, i div 2]:= LandBackPixel(i, t)

           end

       else

           if ((Land[t, i] and lfObject) <> 0) or (disableLandBack and ((Land[t, i] and lfIndestructible) = 0)) then

              if (cReducedQuality and rqBlurryLand) = 0 then

                  LandPixels[t, i]:= 0

              else

                  LandPixels[t div 2, i div 2]:= 0;

FillLandCircleLinesBG:= cnt;

end;

procedure FillLandCircleLinesEBC(x, y, dx, dy: LongInt);

var i, t: LongInt;

begin

t:= y + dy;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

          begin

           if (cReducedQuality and rqBlurryLand) = 0 then

            LandPixels[t, i]:= cExplosionBorderColor

          else

            LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

          Land[t, i]:= Land[t, i] or lfDamaged;

          //Despeckle(i, t);

          LandDirty[t div 32, i div 32]:= 1;

          end;

t:= y - dy;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dx, 0) to Min(x + dx, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

          begin

           if (cReducedQuality and rqBlurryLand) = 0 then

              LandPixels[t, i]:= cExplosionBorderColor

            else

              LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

          Land[t, i]:= Land[t, i] or lfDamaged;

          //Despeckle(i, t);

          LandDirty[t div 32, i div 32]:= 1;

          end;

t:= y + dx;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

           begin

           if (cReducedQuality and rqBlurryLand) = 0 then

           LandPixels[t, i]:= cExplosionBorderColor

            else

           LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

           Land[t, i]:= Land[t, i] or lfDamaged;

           //Despeckle(i, t);

           LandDirty[t div 32, i div 32]:= 1;

           end;

t:= y - dx;

if (t and LAND_HEIGHT_MASK) = 0 then

   for i:= Max(x - dy, 0) to Min(x + dy, LAND_WIDTH - 1) do

       if ((Land[t, i] and lfBasic) <> 0) or ((Land[t, i] and lfObject) <> 0) then

          begin

           if (cReducedQuality and rqBlurryLand) = 0 then

          LandPixels[t, i]:= cExplosionBorderColor

            else

          LandPixels[t div 2, i div 2]:= cExplosionBorderColor;

          Land[t, i]:= Land[t, i] or lfDamaged;

          //Despeckle(i, y - dy);

          LandDirty[t div 32, i div 32]:= 1;

          end;

end;

function DrawExplosion(X, Y, Radius: LongInt): Longword;

var dx, dy, ty, tx, d: LongInt;

    cnt: Longword;

begin

// draw background land texture

    begin

    cnt:= 0;

    dx:= 0;

    dy:= Radius;

    d:= 3 - 2 * Radius;

    while (dx < dy) do

        begin

        inc(cnt, FillLandCircleLinesBG(x, y, dx, dy));

        if (d < 0)

        then d:= d + 4 * dx + 6

        else begin

            d:= d + 4 * (dx - dy) + 10;

            dec(dy)

            end;

        inc(dx)

        end;

    if (dx = dy) then inc(cnt, FillLandCircleLinesBG(x, y, dx, dy));

    end;

// draw a hole in land

if Radius > 20 then

    begin

    dx:= 0;

    dy:= Radius - 15;

    d:= 3 - 2 * dy;

    while (dx < dy) do

        begin

        FillLandCircleLines0(x, y, dx, dy);

        if (d < 0)

        then d:= d + 4 * dx + 6

        else begin

            d:= d + 4 * (dx - dy) + 10;

            dec(dy)

            end;

        inc(dx)

        end;

    if (dx = dy) then FillLandCircleLines0(x, y, dx, dy);

    end;

  // FillRoundInLand after erasing land pixels to allow Land 0 check for mask.png to function

    FillRoundInLand(X, Y, Radius, 0);

// draw explosion border

    begin

    inc(Radius, 4);

    dx:= 0;

    dy:= Radius;

    d:= 3 - 2 * Radius;

    while (dx < dy) do

        begin

        FillLandCircleLinesEBC(x, y, dx, dy);

        if (d < 0)

        then d:= d + 4 * dx + 6

        else begin

            d:= d + 4 * (dx - dy) + 10;

            dec(dy)

            end;

        inc(dx)

        end;

    if (dx = dy) then FillLandCircleLinesEBC(x, y, dx, dy);

    end;

tx:= Max(X - Radius - 1, 0);

dx:= Min(X + Radius + 1, LAND_WIDTH) - tx;

ty:= Max(Y - Radius - 1, 0);

dy:= Min(Y + Radius + 1, LAND_HEIGHT) - ty;

UpdateLandTexture(tx, dx, ty, dy);

DrawExplosion:= cnt

end;

procedure DrawHLinesExplosions(ar: PRangeArray; Radius: LongInt; y, dY: LongInt; Count: Byte);

var tx, ty, i: LongInt;

begin

for i:= 0 to Pred(Count) do

    begin

    for ty:= Max(y - Radius, 0) to Min(y + Radius, LAND_HEIGHT) do

        for tx:= Max(0, ar^[i].Left - Radius) to Min(LAND_WIDTH, ar^[i].Right + Radius) do

            if ((Land[ty, tx] and lfBasic) <> 0) and not disableLandBack then

                if (cReducedQuality and rqBlurryLand) = 0 then

                    LandPixels[ty, tx]:= LandBackPixel(tx, ty)

                else

                    LandPixels[ty div 2, tx div 2]:= LandBackPixel(tx, ty)

            else

                if ((Land[ty, tx] and lfObject) <> 0) or (disableLandBack and ((Land[ty, tx] and lfIndestructible) = 0)) then

                    if (cReducedQuality and rqBlurryLand) = 0 then

                        LandPixels[ty, tx]:= 0

                    else

                        LandPixels[ty div 2, tx div 2]:= 0;

    inc(y, dY)

    end;

inc(Radius, 4);

dec(y, Count * dY);

for i:= 0 to Pred(Count) do

    begin

    for ty:= Max(y - Radius, 0) to Min(y + Radius, LAND_HEIGHT) do

        for tx:= Max(0, ar^[i].Left - Radius) to Min(LAND_WIDTH, ar^[i].Right + Radius) do

            if ((Land[ty, tx] and lfBasic) <> 0) or ((Land[ty, tx] and lfObject) <> 0) then

                begin

                    if (cReducedQuality and rqBlurryLand) = 0 then

                        LandPixels[ty, tx]:= cExplosionBorderColor

                    else

                        LandPixels[ty div 2, tx div 2]:= cExplosionBorderColor;

                Land[ty, tx]:= Land[ty, tx] or lfDamaged;

                LandDirty[ty div 32, tx div 32]:= 1;

                end;

    inc(y, dY)

    end;

UpdateLandTexture(0, LAND_WIDTH, 0, LAND_HEIGHT)

end;

//

//  - (dX, dY) - direction, vector of length = 0.5

//

procedure DrawTunnel(X, Y, dX, dY: hwFloat; ticks, HalfWidth: LongInt);